Fichier BAT pour activer/désactiver Ethernet sous Windows 11

[HerveP]

Bonjour.
Ayant déjà un fichier BAT pour activer/désactiver la connexion réseau sous Windows 7 à 10 (renommer “Connexion au réseau local” en “Ethernet” sous Windows 7), dont voici le code :

Code : Tout sélectionner

@echo off
setlocal enableextensions disabledelayedexpansion
chcp 1252 >nul
color 0A
set keyword=Ethernet
wmic /output:"%TMP%\nic_wmic.csv" nic where "NetConnectionID !=NULL" get netconnectionid,netconnectionstatus /format:csv
for /f "tokens=2,3 delims=," %%A in ('find "%keyword%" "%TMP%\nic_wmic.csv"') do if not defined id (set "id=%%A" & set "status=%%B")
if %status% equ 0 (set action=ENABLED) else (set action=DISABLED)
if %status% equ 4 (set action=ENABLED)
netsh interface set interface "%id%" admin=%action%
exit

, je constate qu'il ne fonctionne pas sous Windows 11 25h2…
Mais il fut un temps où j'en avais enregistré un autre :

Code : Tout sélectionner

echo off
cls 
:start
echo Choix 1
echo Choix 2
set /p choice=1 or 2 ?
if '%Choice%'=='1' goto :choice1
if '%Choice%'=='2' goto :choice2
echo "%Choice%" is not a valid option. Please try again. 
echo
goto start
:choice1
netsh interface set interface "Ethernet" enable
goto end 
:end
pause
exit  
:choice2
netsh interface set interface "Ethernet" disable
goto end 
:end
pause
exit

qui, lui, fonctionne avec un raccourci en mode administrateur. Seulement, je désire qu'il fonctionne comme le premier à savoir :
* si Ethernet est actif, il le désactive,
* Et si Ethernet est désactivé, il l'active sans passer par l'affichage de l'invite de commande, en mode automatique.
Est-ce que c'est possible ? Et comment faire ?
D'avance merci. Cordialement.

[Julien]

Bonjour,

Le script échoue sous Windows 11 suite à la suppression de l'outil wmic par Microsoft. Il faut maintenant utiliser netsh.

A essayer, en tant qu'admin.

Code : Tout sélectionner

@echo off
chcp 1252 >nul
set "interface=Ethernet"

:: Vérifie si l'interface contient le mot "Désactivé" dans son statut
netsh interface show interface "%interface%" | findstr /C:"Désactivé" >nul

:: Si le mot est trouvé (errorlevel 0) on active sinon on désactive
if %errorlevel% equ 0 (
    netsh interface set interface "%interface%" admin=enabled
) else (
    netsh interface set interface "%interface%" admin=disabled
)
exit

Remarque : en supposant que les W11 sont en français, j'ai mis "Désactivé". Si c'est en anglais, il faut le changer pour "Disabled".

[HerveP]

Merci beaucoup. Je vais essayer quand j'aurai réinstallé Win-11-25h2 !
Cordialement !